FX取引ルール確立のために

取引方針が定まらぬ臆病者の外国為替証拠金取引の行方。 取引ルールの柱にテクニカルな売買サインを導入中。システム開発状況を全て公開。

スポンサーサイト

上記の広告は1ヶ月以上更新のないブログに表示されています。
新しい記事を書く事で広告が消せます。

アジア時間高値安値ブレイクインジケ-タ 3日平均値幅

”アジア時間高値安値ブレイクインジケ-タ 3日平均値幅”のCTLを掲載します。

アジア時間の高値安値インジケタind_asia_time_highlow_aと
4本値インジケタind_day_4priceが
インストールされていないと動作しません。


これを元にしてストラテジーを作ることができます。

入力項目の意味:
barminute 分足の数値(15分足チャートなら15にします)
  → 自動化しました。
  func_barminuteというファンクションがインストールされていないと動作しません。


start hour 高値安値を表示する時間帯の初めの時刻
end hour 高値安値を表示する時間帯の終わりの時刻
delta エントリーラインをアジア高値安値ラインからシフトする割合です
       0.1を入力すると平均値幅の10%だけシフトします
profit ratio 利益確定のレベルを決めます
       0.5を入力すると利確ラインをエントリーラインから平均値幅の50%だけ離して設定します
loss ratio 損きりのレベルを決めます
       0.35を入力すると損きりラインをエントリーラインから平均値幅の35%だけ離して設定します

CTLは続きを読むを参照してください

検証にはGFTのdealbook360を使っています
自前の検証をお勧めします
口座開設はこちらから

FX


チャートの時間足を自動検出する形に改定しました

/*アジア時間高値安値ブレイクインジケ-タ 3日平均値幅 */

indicator ind_asia_time_highlow_break_3av;
input start_hour=6,end_hour=16,delta=0,
profit_ratio=0.50,loss_ratio=0.35 ;
draw buy_line("buy",dot_line,green),sell_line("sell",dot_line,red),
prflong_line1("prflong1",solid_line,green),
prflong_line2("prflong2",solid_line,green),
losslong_line("losslong",solid_line,green),
prfshort_line1("prfshort1",solid_line,red),
prfshort_line2("prfshort2",solid_line,red),
lossshort_line("lossshort",solid_line,red);
vars lst(number),i(number),barminute(number),
losscut(series), profit(series),
line_high(series),line_low(series),
day_width(series),
prflong(series),prfshort(series),
losslong(series),lossshort(series),
line_high_1(series),line_low_1(series),
line_high_2(series),line_low_2(series),
line_high_3(series),line_low_3(series),
line_asia_high(series),line_asia_low(series) ;

begin
lst := back(close) ;
barminute := func_barminute();

if lst < front(close)+(4*1440/barminute) then return;
{ アジア時間の高値安値インジケタの呼び出し }
ind_asia_time_highlow_a(barminute,start_hour,end_hour);
{ アジア時間の高値安値を定義します }
line_asia_high := ind_asia_time_highlow_a.line_high ;
line_asia_low := ind_asia_time_highlow_a.line_low ;
{ 4本値インジケタの呼び出し }
ind_day_4price(barminute,start_hour);
{ 日の高値安値を定義します }
line_high := ind_day_4price.line_high ;
line_low := ind_day_4price.line_low ;

{ 1日前、2日前、3日前の高値安値を定義します }
line_high_1 := displace(line_high,1440/barminute);
line_low_1 := displace(line_low,1440/barminute);
line_high_2 := displace(line_high,2880/barminute);
line_low_2 := displace(line_low,2880/barminute);
line_high_3 := displace(line_high,4320/barminute);
line_low_3 := displace(line_low,4320/barminute);
{ 3日間の値幅を求めて平均値幅を計算します }
day_width := (line_high_1-line_low_1+line_high_2-line_low_2+line_high_3-line_low_3)/3;
{ 損きりレベルと利確レベルを平均値幅の割合として定義します }
losscut := loss_ratio*(day_width) ;
profit := profit_ratio*day_width ;
{ 買い、売りのエントリレベルを定義します }
{ 値幅の指定割合分だけアジア高値安値ラインからシフト出来ます }
buy_line := line_asia_high+(delta*day_width) ;
sell_line := line_asia_low-(delta*day_width);
{ 買いの利確ラインを定義します }
prflong := buy_line+profit ;
prflong_line1 := prflong ;
prflong_line2 := buy_line+(2*profit);
{ 売りの利確ラインを定義します }
prfshort := sell_line-profit ;
prfshort_line1 := prfshort ;
prfshort_line2 := sell_line-(2*profit) ;
  { 買いの損きりラインを定義します } 
losslong := buy_line-losscut ;
losslong_line := losslong ;
{ 売りの損きりラインを定義します }
lossshort := sell_line+losscut ;
lossshort_line := lossshort ;

end.
スポンサーサイト

コメント

コメントの投稿


管理者にだけ表示を許可する

トラックバック

トラックバックURLはこちら
http://fxrun.blog55.fc2.com/tb.php/582-c84eb273
この記事にトラックバックする(FC2ブログユーザー)

FC2Ad

上記広告は1ヶ月以上更新のないブログに表示されています。新しい記事を書くことで広告を消せます。